Usare l'oggetto email CDOSYS - Script ASP

Esempio di utilizzo dell'oggetto email CDOSYS.
Gli elementi (opzionali) non sono richiesti per l'uso standard dell'oggetto ma possono essere aggiunti per inserire funzioni ulteriori al nostro script.

Desidero ricordare che per utilizzare l'oggetto CDOSYS è necessario allegare all'oggetto la configurazione del server per evitare di scontrarsi con l'errore CDO.Message.1.

<%

' Dichiara l'oggetto email e la configurazione 
Dim objMail, objConfig 

' Crea l'oggetto email
Set objMail = Server.CreateObject("CDO.Message") 

' ==================================== 
'Dimensiona l'oggetto configurazione 
Set objConfig = Server.cr&#101;ateObject("CDO.Configuration") 

' Imposta le configurazioni 
With objConfig 

' Server SMTP di uscita 
' Esempio mail.dominio.it 
.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "iltuoserverdiuscita"

' Porta SMTP 
.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25 

' Porta CDO
.Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 

' Timeout 
.Fields("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60 

.Fields.Update
End With 

' Assegna le configurazioni
Set objMail.Configuration = objConfig 

' ==================================== 

' Assegna all'oggetto le proprietà necessarie

' Mittente dell'email (indirizzo)
objMail.From = "mittente@dominio.com"

' Destinatario dell'email (indirizzo) 
objMail.To = "destinatario@dominio.com" 

' Cc e Bcc (opzionale) 
objMail.Cc = "altroindirizzo@dominio.com; ancora@dominio.com" 
objMail.Bcc = "altroindirizzo@dominio.com; ancora@dominio.com" 

' Oggetto dell'email 
objMail.Subject = "Oggetto della mail" 

' Valore di priorità 
objMail.Fields("urn:schemas:httpmail:importance").Value = 2 
objMail.Fields.Update() 

' Allegare un file 
objMail.AddAttachment("d:\inetpub\webs\tuodominiocom\file.zip") 

' Corpo del messaggio 
objMail.TextBody = "Testo della mail" ' Formato Testo 
objMail.HTMLBody = "Testo della mail" ' Formato HTML 

' Invia l'email 
objMail.Send() 

' Distruggi l'oggetto 
Set objMail = Nothing 

%>