Semplice form mail con CDOSYS - Script ASP

L'esempio riporta un semplice form mail in ASP usando l'oggetto CDOSYS.

Alla prima visualizzazione il codice mostra una semplice form per l'immissione dei dati.
Una volta confermata lo script ricarica la pagina ed invia una email ad un indirizzo preimpostato richiamando i campi dalla form.

ATTENZIONE: da notare come l'esempio non esegua nessun tipo di controllo sulla presenza di dati nei campi form che se non compilati potrebbero generare errore nell'invio dell'email.

Ulteriori campi form sono inseribili sul modello di quelli già presenti.

<% 

' Controlla invio 
if Request.QueryString("invia") = "true" AND Request.Form("submit") = "invia" then 

Dim objMail, objConfig 

' Crea l'oggetto email 
Set objMail = Server.CreateObject("CDO.Message") 

' Dimensiona l'oggetto configurazione
Set objConfig = Server.CreateObject ("CDO.Configuration")

' Imposta le configurazioni 
With objConfig 

' Server SMTP di uscita 
' ATTENZIONE! Usare il proprio indirizzo di server email! 
' E' FONDAMENTALE per l'invio della email 
.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "mail.miosito.com" 

' Porta SMTP
.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25 

' Porta CDO 
.Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 

' Timeout 
.Fields("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60 
.Fields.Update 

End With 

' Assegna le configurazioni 
Set objMail.Configuration = objConfig 

' Assegna all'oggetto le proprietà necessarie 
objMail.From = "mittente@dominio.com" ' Mittente 
objMail.To = Request.Form("email") ' Destinatario
objMail.Subject = Request.Form("oggetto") ' Oggetto 
objMail.HTMLBody = Request.Form("messaggio") ' Messaggio

' Invia l'email 
objMail.Send() 

Set objMail = Nothing 

Response.Write("Email inviata correttamente " &_ 
"all'indirizzo " &_ 
Request.Form("email")) 

else %> 
<form name="formail" method="post" action="?invia=true"> 
<table align="center" cellpadding="3" cellspacing="1">
<tr> 
<td>Email</td> 
<td><input type="text" name="email" /></td> 
</tr> 
<tr> 
<td>Oggetto</td> 
<td><input type="text" name="oggetto" /></td> 
</tr> 
<tr> 
<td>Messaggio</td> 
<td><textarea name="messaggio"></textarea></td> 
</tr> 
<tr> 
<td colspan="2"> <input type="submit" value="invia" name="submit" /> </td> 
</tr>
</table> 
</form> 
<% end if %>